Customization of Defaults

default_digits(render::AbstractRenderType, x::AbstractRegressionStatistic)

Default for regression statistics (R2, AIC), defaults to the general setting of 3 digits

Examples

julia> RegressionTables.default_digits(::AbstractRenderType, x::RegressionTables.AbstractRegressionStatistic) = 4;

julia> x = R2(1.234567);

julia> repr(AsciiTable(), x)
"1.2346"

julia> repr(LatexTable(), x)
"1.2346"

default_digits(render::AbstractRenderType, x::AbstractUnderStatistic)

Default for under statistics (TStat, StdError), defaults to the general setting of 3 digits

Examples

julia> RegressionTables.default_digits(::RegressionTables.AbstractAscii, x::RegressionTables.AbstractUnderStatistic) = 4;

julia> x = StdError(1.234567);

julia> repr(AsciiTable(), x)
"(1.2346)"

julia> repr(LatexTable(), x) # unchanged since the default_digits was only changed for Ascii
"(1.235)"

default_digits(render::AbstractRenderType, x::.CoefValue)

Default for CoefValue, defaults to the general setting of 3 digits

Examples

julia> RegressionTables.default_digits(::AbstractRenderType, x::RegressionTables.CoefValue) = 2

julia> x = RegressionTables.CoefValue(1.234567, 1); # 1 is for the p value

julia> repr(HtmlTable(), x)
"1.23"

default_digits(render::AbstractRenderType, x)

The default for for all other values not otherwise specified, defaults to 3 digits

Examples

julia> RegressionTables.default_digits(::AbstractRenderType, x) = 4

julia> x = 1.234567;

julia> y = TStat(1.234567);

julia> repr(LatexTable(), x)
"1.2346"

julia> repr(LatexTable(), y) # Also changes since the default_digits for other types default to this value
"(1.2346)"

default_section_order(render::AbstractRenderType)

Default section order for the table, defaults to [:groups, :depvar, :number_regressions, :break, :coef, :break, :fe, :break, :randomeffects, :break, :clusters, :break, :regtype, :break, :controls, :break, :stats, :extralines]

:break is a special keyword that adds a line break between sections (e.g. between \midrule in Latex)

default_align(render::AbstractRenderType)

Defaults to :r for all render types, possible options are :r, :l, :c This affects each part of the table after the header and the leftmost column always has the :l alignment

default_header_align(render::AbstractRenderType)

Defaults to :c for all render types, possible options are :r, :l, :c This affects the header (all sections up before :coef, see default_section_order) of each part of the table

default_depvar(render::AbstractRenderType)

Defaults to true for all render types, if false the dependent variable ("Y") is not printed

default_number_regressions(render::AbstractRenderType, rrs)

Defaults to true if there is more than one regression, if false the regression number is not printed

default_print_fe(render::AbstractRenderType, rrs)

Defaults to true, but the section will not be printed if there are not fixed effects. If false the fixed effects are not printed

default_groups(render::AbstractRenderType, rrs)

Defaults to nothing, groups are printed above the dependent variable Setting a default should also use rrs (the regression results) since that determines the number of columns in the table.

default_extralines(render::AbstractRenderType, rrs)

Defaults to nothing, extra lines are printed at the end of the table. Setting a default should also use rrs (the regression results) since that determines the number of columns in the table.

default_keep(render::AbstractRenderType, rrs)

Defaults to Vector{String}(), which means all variables are printed. Also see Keep Drop and Order Arguments for more information.

default_drop(render::AbstractRenderType, rrs)

Defaults to Vector{String}(), which means no variables are dropped. Also see Keep Drop and Order Arguments for more information.

default_order(render::AbstractRenderType, rrs)

Defaults to Vector{String}(), which means the order is not changed. Also see Keep Drop and Order Arguments for more information.

In settings where the primary variables of interest are static throughout the tests, it can help to set default_order to a regex that includes that variable. For example, if the primary variables are interactions, then

RegressionTables.default_order(::AbstractRenderType, rrs) = [r" & "]

will prioritize the interactions in the table.

default_fixedeffects(render::AbstractRenderType, rrs)

Defaults to Vector{String}(), which means any fixed effects available are printed.

default_labels(render::AbstractRenderType, rrs)

Defaults to Dict{String, String}(), which means no coefficients are changed. If you have a master dictionary of variables to change, it can help to set default_labels to that dictionary. It is also possible to set default_labels for each table type, allowing for labels to escape special characters in Latex.

Examples

RegressionTables.default_labels(render::AbstractRenderType, rrs) = Dict("first" => "New First", "second" => "X > Y")
RegressionTables.default_labels(render::RegressionTables.AbstractLatex, rrs) = Dict("first" => "New First", "second" => "X $>$ Y")

default_transform_labels(render::AbstractRenderType, rrs) = Dict{String, String}()
default_transform_labels(render::AbstractLatex, rrs) = :latex

transform_labels apply a replace function to the coefficients, dependent variables and fixed effects. The default for AbstractLatex is used to escape special characters in Latex.

default_below_statistic(render::AbstractRenderType)

Defaults to StdError, which means the standard error is printed below the coefficient. See AbstractUnderStatistic for more information.

default_stat_below(render::AbstractRenderType)

Defaults to true, which means the standard error (or t-stat) is printed below the coefficient. If false, the standard error is printed to the right of the coefficient (in the same column)

default_render(rrs)

Defaults to AsciiTable(), any concrete AbstractRenderType is allowed

default_file(render::AbstractRenderType, renderSettings::Tuple{<:AbstractRenderType, String}, rrs)

Defaults to nothing, which means no file is saved.

default_print_fe_suffix(render::AbstractRenderType)

Whether or not a suffix will be applied to the fixed effects, defaults to true.

default_print_control_indicator(render::AbstractRenderType)

Defaults to true, which means if the regression has any variables ommitted (due to keep or drop), then a line is placed with Controls and Yes.

default_standardize_coef(render::AbstractRenderType, rrs)

Defaults to false. Standardizing the coefficient divides the coefficient by its standard deviation and multiplies it by the standard deviation of the dependent variable. It is only possible for models that store the matrix, such as those in GLM.jl and MixedModels.jl. If it is not possible, the coefficients will not change.

default_print_estimator(render::AbstractRenderType, rrs)

Defaults to true if more than one type of estimator is used. For example, if all regressions are "OLS", then this section will default to false, while if one regression is "OLS" and another is "IV", then this section will default to true.

default_regression_statistics(rr::RegressionModel)

Returns a vector of AbstractRegressionStatistic objects. This is used to display the statistics in the table. This is customizable for each RegressionModel type. The default is to return a vector of Nobs and R2.

default_regression_statistics(render::AbstractRenderType, rrs)

Defaults to a union of the default_regression_statistics for each regression. For example, an "OLS" regression (with no fixed effects) will default to including [Nobs, R2], and a Probit regression will include [Nobs, PseudoR2], so the default will be [Nobs, R2, PseudoR2].

default_print_randomeffects(render::AbstractRenderType, rrs)

Defaults to true, but the section will not be printed if there are not random effects.

default_print_clusters(render::AbstractRenderType, rrs)

Defaults to false, which means no cluster information is printed.

default_use_relabeled_values(render::AbstractRenderType, rrs) = true

Defaults to true, which means the keep, drop and order arguments will use the relabeled values instead of the original values.

default_confint_level(render::AbstractRenderType, rrs)

Defaults to 0.95, which means the 95% confidence interval is printed below the coefficient.

default_breaks(render::AbstractRenderType)

The default cutoffs for the number of "*" (or other value set by default_symbol). The default is [0.001, 0.01, 0.05], corresponding to a p-value of 0.1%, 1%, and 5%.

default_symbol(render::AbstractRenderType)

The default symbol to use for the p-value. The default is '*'.

interaction_combine(render::AbstractRenderType) = " & "
interaction_combine(render::AbstractLatex) = " \$\times\$ "
interaction_combine(render::AbstractHtml) = " × "

Used to separate pieces of InteractedCoefName and defaults to:

• " & " in the general case
• "$ \times $" in Latex
• " × " in HTML

Change this by rerunning the function with the desired default, for example:

RegressionTables.interaction_combine(render::AbstractLatex) = " \& "

categorical_equal(render::AbstractRenderType)

Used to separate the name and level of CategoricalCoefName and defaults to ": ".

random_effect_separator(render::AbstractRenderType)

Used to separate the left and right hand side of RandomEffectCoefName and defaults to " | ".

estim_decorator(render::AbstractRenderType, s, pval; breaks=default_breaks(render), sym=default_symbol(render))

Decorates a value with a symbol based on p-value. In many journals, the symbol is a * and the p-value has three cutoffs, either 0.001, 0.01, and 0.05 or 0.01, 0.05, and 0.10.

It is possible to wrap the symbols in an additional element, for example, in Latex it is common to wrap the symbol as a superscript. To do so in all tables, run

RegressionTables.wrapper(::AbstractLatex, deco) = "\$^{$deco}\$"

It is also possible to change the cutoffs or symbols. To change the cutoffs, run

RegressionTables.default_breaks(::AbstractLatex) = [0.01, 0.05, 0.10] # make sure these are in order

And to change the cutoffs run

RegressionTables.default_symbol(::AbstractLatex) = "x" # or whatever you want

below_decoration(render::AbstractRenderType, s)

Used to decorate a string below the main string and defaults to "($s)". Change this by running:

RegressionTables.below_decoration(render::AbstractRenderType, s) = "($s)"

number_regressions_decoration(render::AbstractRenderType, s)

Used to decorate the regression number (e.g., "(1)") and defaults to "($s)". Change this by running:

RegressionTables.number_regressions_decoration(render::AbstractRenderType, s) = "($s)"

fe_suffix(render::AbstractRenderType)

Used to add a suffix to the fixed effects and defaults to " Fixed Effects". Change this by running:

RegressionTables.fe_suffix(render::AbstractRenderType) = " Fixed Effects"

wrapper(render::AbstractRenderType, s)

Used to wrap a string, particularly for estim_decorator and defaults to s (i.e., no wrapper). For example, to wrap the stars in Latex, run:

RegressionTables.wrapper(::AbstractLatex, deco) = "$^{$deco}$"

fe_value(render::AbstractRenderType, v)

Determines how to render a yes/no value for fixed effects, defaults to "Yes" and "". Can be changed by running:

RegressionTables.fe_value(render::AbstractRenderType, v) = v ? "Yes" : "No"

cluster_suffix(render::AbstractRenderType)

Used to add a suffix to the clustering and defaults to " Clustering". Change this by running:

RegressionTables.cluster_suffix(render::AbstractRenderType) = " Clustering"

label(render::AbstractRenderType, x::Type{Nobs}) = "N"
label(render::AbstractLatex, x::Type{Nobs}) = "\$N\$"
label(render::AbstractHtml, x::Type{Nobs}) = "<i>N</i>"

label(render::AbstractRenderType, x::Type{R2}) = "R2"
label(render::AbstractLatex, x::Type{R2}) = "\$R^2\$"
label(render::AbstractHtml, x::Type{R2}) = "<i>R</i><sup>2</sup>"

label(render::AbstractRenderType, x::Type{R2McFadden}) = "Pseudo " * label(render, R2)

label(render::AbstractRenderType, x::Type{R2CoxSnell}) = "Cox-Snell " * label(render, R2)

label(render::AbstractRenderType, x::Type{R2Nagelkerke}) = "Nagelkerke " * label(render, R2)

label(render::AbstractRenderType, x::Type{R2Deviance}) = "Deviance " * label(render, R2)

label(render::AbstractRenderType, x::Type{AdjR2}) = "Adjusted " * label(render, R2)

label(render::AbstractRenderType, x::Type{AdjR2McFadden}) = "Pseudo " * label(render, AdjR2)

label(render::AbstractRenderType, x::Type{AdjR2Deviance}) = "Deviance " * label(render, AdjR2)

label(render::AbstractRenderType, x::Type{DOF}) = "Degrees of Freedom"

label(render::AbstractRenderType, x::Type{LogLikelihood}) = "Log Likelihood"

label(render::AbstractRenderType, x::Type{AIC}) = "AIC"

label(render::AbstractRenderType, x::Type{AICC}) = "AICC"

label(render::AbstractRenderType, x::Type{BIC}) = "BIC"

label(render::AbstractRenderType, x::Type{FStat}) = "F"
label(render::AbstractLatex, x::Type{FStat}) = "\$F\$"
label(render::AbstractHtml, x::Type{FStat}) = "<i>F</i>"

label(render::AbstractRenderType, x::Type{FStatPValue}) = label(render, FStat) * "-test " * label_p(render) * " value"

label(render::AbstractRenderType, x::Type{FStatIV}) = "First-stage " * label(render, FStat) * " statistic"

label(render::AbstractRenderType, x::Type{FStatIVPValue}) = "First-stage " * label_p(render) * " value"

label(render::AbstractRenderType, x::Type{R2Within}) = "Within " * label(render, R2)

label(render::AbstractRenderType, x::Type{RegressionType}) = "Estimator"

label(render::AbstractRenderType, x::Type{HasControls}) = "Controls"

label(render::AbstractRenderType, x::Type{RegressionNumbers}) = ""

label_p(render::AbstractRenderType) = "p"
label_p(render::AbstractLatex) = "\$p\$"
label_p(render::AbstractHtml) = "<i>p</i>"

label_ols(render::AbstractRenderType) = "OLS"

Also see RegressionType

label_iv(render::AbstractRenderType) = "IV"

Also see RegressionType

label_distribution(render::AbstractRenderType, d::D) where {D <: UnivariateDistribution} = string(Base.typename(D).wrapper)
label_distribution(render::AbstractRenderType, d::NegativeBinomial) = "Negative Binomial"
label_distribution(render::AbstractRenderType, d::InverseGaussian) = "Inverse Gaussian"

How to label non-linear regressions and defaults to the name of the distribution. For example, Probit will be "Probit". Two exceptions are given for NegativeBinomial and InverseGaussian, which are "Negative Binomial" and "Inverse Gaussian", respectively. This can be changed for a specific distribution by running:

RegressionTables.label_distribution(render::AbstractRenderType, d::Poisson) = "Poisson"